(转)微信多开破解源码

感谢 aar群: 本群第二丑(153080xx46) 分享代码

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add(
button={cls="button";text="Button";left=152;top=123;right=303;bottom=179;z=1}
)
/*}}*/

import process
import console
var wechatpath = "C:\Program Files (x86)\Tencent\WeChat\WeChat.exe"

winform.button.oncommand = function(id,event){
    var prcs = process(wechatpath)
    if(!prcs) return ; 
    var ok,HandleCount = ::Kernel32.GetProcessHandleCount(prcs.handle,{int c})
    HandleCount = HandleCount.c
    var sHandle,i = 0,0
    var t = {ptr v}
    var buf = raw.buffer(8192)
    var buflen,bufstr
    var handletab = {}
    var bufobj = {
    	word l;
    	ustring name;
    }
    while(sHandle < 65536){
    	if( ::Kernel32.DuplicateHandle(prcs.handle,sHandle,process.getHandle(),t,0,false,2) ){
    		if(::Ntdll.ZwQueryObject(t.v,1,buf,8192,0) == 0){
    			raw.convert(buf,bufobj)
    			table.push(handletab,{
    				handle = sHandle;
    				name = bufobj.name
    			})
    		}
    		raw.closehandle(t.v)
    		i++
    		if(i == HandleCount) break ;
    	}
    	sHandle += 4
    }
    for(i=1;#handletab;1){
    	if(handletab[i].name && string.indexOf(handletab[i].name,"_WeChat_App_Instance_Identity_Mutex_Name")){
    		if(::Kernel32.DuplicateHandle(prcs.handle,handletab[i].handle,process.getHandle(),t,0,false,1)){
    			raw.closehandle(t.v)
    		}
    	}
    }
}


winform.show();
win.loopMessage();
return winform;